mirror of
https://github.com/RYDE-WORK/pybind11.git
synced 2026-01-22 23:15:36 +08:00
2e5f5c4cf8
* fix: support CMake 3.27, drop 3.4 Signed-off-by: Henry Schreiner <henryschreineriii@gmail.com> * Update upgrade.rst * Update upgrade.rst * Update upgrade.rst --------- Signed-off-by: Henry Schreiner <henryschreineriii@gmail.com>
40 lines
1.3 KiB
CMake
40 lines
1.3 KiB
CMake
cmake_minimum_required(VERSION 3.5)
|
|
project(test_installed_module CXX)
|
|
|
|
# The `cmake_minimum_required(VERSION 3.5...3.26)` syntax does not work with
|
|
# some versions of VS that have a patched CMake 3.11. This forces us to emulate
|
|
# the behavior using the following workaround:
|
|
if(${CMAKE_VERSION} VERSION_LESS 3.26)
|
|
cmake_policy(VERSION ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION})
|
|
else()
|
|
cmake_policy(VERSION 3.26)
|
|
endif()
|
|
|
|
project(test_installed_function CXX)
|
|
|
|
find_package(pybind11 CONFIG REQUIRED)
|
|
message(
|
|
STATUS "Found pybind11 v${pybind11_VERSION} ${pybind11_VERSION_TYPE}: ${pybind11_INCLUDE_DIRS}")
|
|
|
|
pybind11_add_module(test_installed_function SHARED NO_EXTRAS ../main.cpp)
|
|
set_target_properties(test_installed_function PROPERTIES OUTPUT_NAME test_cmake_build)
|
|
|
|
if(DEFINED Python_EXECUTABLE)
|
|
set(_Python_EXECUTABLE "${Python_EXECUTABLE}")
|
|
elseif(DEFINED PYTHON_EXECUTABLE)
|
|
set(_Python_EXECUTABLE "${PYTHON_EXECUTABLE}")
|
|
else()
|
|
message(FATAL_ERROR "No Python executable defined (should not be possible at this stage)")
|
|
endif()
|
|
|
|
add_custom_target(
|
|
check_installed_function
|
|
${CMAKE_COMMAND}
|
|
-E
|
|
env
|
|
PYTHONPATH=$<TARGET_FILE_DIR:test_installed_function>
|
|
${_Python_EXECUTABLE}
|
|
${PROJECT_SOURCE_DIR}/../test.py
|
|
${PROJECT_NAME}
|
|
DEPENDS test_installed_function)
|